Only several programs or settings require me to save data within the Windows standard directory system. These I need to sync into the My Data locations (Start Menu, App Launcher, Favorites, Send To, etc.).

The problem is to sync in a specific order, and to easily add new Folder Pairs. I also wanted to see what SyncToy actually did (could be at a later time) and I was annoyed at looking at blank Cmd windows.

The following is what I came up with, and I hope you might like it as well.

Const WriteLogs = True ' True to create Log Files for each Sync, False not to
Const ProgramDirectory = "C:\Program Files\SyncToy 2.0" ' The Directory where SyncToy is installed
Const LogsDirectory = "C:\My Data\My System\SyncToy\Logs" ' The Directory where the Log Files are to be written
Const DataFile = "SyncFolder List.txt" ' The name of the SyncFolder data file

Set wshShell = WScript.CreateObject ("WScript.shell") ' Create the WScript Objects to execute the program and display PopUps

Set objFSO = CreateObject("Scripting.FileSystemObject") ' Create the FileSystemObject
Set objDataFile = objFSO.OpenTextFile( wshShell.CurrentDirectory & "\" & DataFile, 1) ' Create the TextStream for the Data File

Set objParameters = WScript.Arguments ' Create Argument object to read the parameters passed to the script

strAction = objParameters(0) ' Store the Action to be taken, Hibernate, Restart, Shutdown, Standby
strCmd = objParameters(1) ' Store the Program and it's parametets

' Ensure that the requested action is desired
lngMsgBox = MsgBox ("Are you sure you want to " & LCase(strAction) & " the system?", _
	vbYesNo + VBCritical, strAction & " computer")

If lngMsgBox = vbYes then ' If the user wants to continue, do so

    ' This box will disappear after 3 seconds. Display action notification
    intReturn = wshShell.Popup("The computer will now sync and " & LCase(strAction) & ".", 3, _
		strAction & " computer", VBInformation)

	Do While Not objDataFile.AtEndOfStream ' Step through the data file and execute the listed Folder Pair

		strFolderPair = objDataFile.ReadLine ' Read the line containing the Folder Pair name

		If WriteLogs Then ' Set up the CmdLine based on whether or not to create log files

			' Use CMD.exe to execute the command line using piping - otherwise it won't work
			' && allows Cmd.exe to execute multiple commands on 1 line, so display FolderPair in DOS window
			strCmdLine = "Cmd.exe /C Echo Syncing " & strFolderPair & "&&""" & ProgramDirectory &  _
				"\SyncToyCmd.exe"" -R """  & strFolderPair & """ > """ & LogsDirectory & "\" & strFolderPair & ".log"""""

		Else

			' Cmd line if no log file is to be written
			strCmdLine = "Cmd.exe /C Echo Syncing " & strFolderPair & "&&" & ProgramDirectory &  _
				"\SyncToyCmd.exe"" -R """ & 	strFolderPair & """"

		End If

		wshShell.run strCmdLine, 5, True ' Execute the command

	Loop

End If

objDataFile.Close ' Close the datafile

' This box will disappear after 3 seconds. Display Sync Completion and action to be taken
intReturn = wshShell.Popup("Completed syncing files." & vbcrlf & vbcrlf & "The computer will now " & LCase(strAction) & ".", 3, _
	strAction & " computer", VBInformation)

Set objResult = wshShell.exec( "%windir%\System32\" & strCmd ) ' Actually carry out desired action

To use the above code, just create a shortcut to it and add the action (Hibernate, Restart, Shutdown, or Standby) as the first parameter. The second parameter is the program name with it's parameters - "Shutdown.exe /h" for Hibernate (/r for Restart, /s for Shutdown). For Standby it is "C:\My Data\My System\SyncToy\Scripts\Sync with Action.vbs" "Standby" "rundll32.exe PowrProf,SetSuspendState"

The code stores path information in constants so there is only 1 place that needs changing.

The && separates commands in CMD statements, so the action being carried out is echoed in the DOS window.

Lastly, the textfile SyncFolderList.txt is simply a text file with a listing of all of the folder pairs I want synced (each on it's own line)

I created a separate file, Sync All.vbs that does all of the syncing without any other action taking place, it is listed below.

Const WriteLogs = True ' True to create Log Files for each Sync, False not to
Const ProgramDirectory = "C:\Program Files\SyncToy 2.0" ' The Directory where SyncToy is installed
Const LogsDirectory = "C:\My Data\My System\SyncToy\Logs" ' The Directory where the Log Files are to be written
Const DataFile = "SyncFolder List.txt" ' The name of the SyncFolder data file

' Create the WScript Objects to execute the program
Set wshShell = WScript.CreateObject ("WSCript.shell")

Set objFSO = CreateObject("Scripting.FileSystemObject") ' Create the FileSystemObject
Set objDataFile = objFSO.OpenTextFile( wshShell.CurrentDirectory & "\" & DataFile, 1) ' Create the TextStream for the Data File

Do While Not objDataFile.AtEndOfStream ' Step through the data file and execute the listed Folder Pair

	strFolderPair = objDataFile.ReadLine ' Read the line containing the Folder Pair name

	If WriteLogs Then ' Set up the CmdLine based on whether or not to create log files

		' Use CMD.exe to execute the command line using piping - otherwise it won't work
		strCmdLine = "Cmd.exe /C Echo Syncing " & strFolderPair & "&&""" & ProgramDirectory &  "\SyncToyCmd.exe"" -R """  & _
			strFolderPair & """ > """ & LogsDirectory & "\" & strFolderPair & ".log"""""

	Else

		strCmdLine = "Cmd.exe /C Echo Syncing " & strFolderPair & "&&" & ProgramDirectory &  "\SyncToyCmd.exe"" -R """ & 	strFolderPair & """"

	End If

	wshShell.run strCmdLine, 5, True ' Execute the command line

Loop

objDataFile.Close ' Close the text file

To solve the problem of making sure to use these to shutdown, etc., I actually removed all of the shutdown options from the Start Menu and have these shortcuts at the top of my App Launcher on the SideBar.

I hope you and others will find this helpful.

Nice script, tho. I'll make sure to point people your direction, and I'll actually probably end up using a variation myself on my new laptop. Keep up the good work!